Комментарии / Публикации AM2 / OpenTraders - блогплатформа для трейдеров финансовых рынков

Советник на отложенных ордерах / Стол заказов MQL 10

0

Затем сов должен закрывать абсолютно все ордера при достижении сумарного профита

сделал как просили:



//--- Inputs
extern double Lot        = 0.1;      // лот позы
extern double Lots       = 0.5;      // лот отлоги
extern double Profit     = 10;       // профит
extern int Minus         = 333;      // минус в пунтах
extern int Delta         = 30;       // расстояние от цены
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

bool one=1;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   PutButton("B",100,160,"BUY");
   PutButton("S",100,120,"SELL");
   PutButton("C",100,80,"CLOSE");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   ObjectDelete(0,"B");
   ObjectDelete(0,"S");
   ObjectDelete(0,"C");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutButton(string name,int x,int y,string text)
  {
   ObjectCreate(0,name,OBJ_BUTTON,0,0,0);
//--- установим координаты кнопки
   ObjectSetInteger(0,name,OBJPROP_XDISTANCE,x);
   ObjectSetInteger(0,name,OBJPROP_YDISTANCE,y);
//--- установим размер кнопки
   ObjectSetInteger(0,name,OBJPROP_XSIZE,80);
   ObjectSetInteger(0,name,OBJPROP_YSIZE,30);
//--- установим угол графика, относительно которого будут определяться координаты точки
   ObjectSetInteger(0,name,OBJPROP_CORNER,3);
//--- установим текст
   ObjectSetString(0,name,OBJPROP_TEXT,text);
//--- установим шрифт текста
   ObjectSetString(0,name,OBJPROP_FONT,"Arial");
//--- установим размер шрифта
   ObjectSetInteger(0,name,OBJPROP_FONTSIZE,9);
//--- установим цвет текста
   ObjectSetInteger(0,name,OBJPROP_COLOR,Red);
//--- установим цвет фона
   ObjectSetInteger(0,name,OBJPROP_BGCOLOR,White);
//--- установим цвет границы
   ObjectSetInteger(0,name,OBJPROP_BORDER_COLOR,Blue);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
   ObjectSetInteger(0,name,OBJPROP_HIDDEN,false);
//--- установим приоритет на получение события нажатия мыши на графике
   ObjectSetInteger(0,name,OBJPROP_ZORDER,0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price,double lot)
  {
   int r=0;
   color clr=Green;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
     }

   r=OrderSend(NULL,type,lot,NormalizeDouble(price,_Digits),Slip,0,0,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int Points()
  {
   int pp=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0)
              {
               pp=int((OrderOpenPrice()-Bid)/_Point);
              }
            if(OrderType()==1)
              {
               pp=int((Bid-OrderOpenPrice())/_Point);
              }
           }
        }
     }
   return(pp);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int LastType()
  {
   int type=0;

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            type=OrderType();
            break;
           }
        }
     }
   return(type);
  }
//+------------------------------------------------------------------+
//| Профит всех ордеров по типу ордера                               |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Удаление отложенных ордеров                                      |
//+------------------------------------------------------------------+
void DelOrder(int type=-1)
  {
   bool del;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1)
               del=OrderDelete(OrderTicket());
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(AllProfit()>Profit && Profit>0)
      CloseAll();

   if(Points()>Minus && one)
     {
      if(CountOrders(4)<1 && LastType()==1)
         PutOrder(4,Bid+Delta*_Point,Lots);

      if(CountOrders(5)<1 && LastType()==0)
         PutOrder(5,Bid-Delta*_Point,Lots);

      one=0;
     }

   if(CountTrades()<1)
     {
      DelOrder();
      one=1;
     }

   if(ObjectGetInteger(0,"B",OBJPROP_STATE)==1)
     {
      PutOrder(0,Ask,Lot);
      ObjectSetInteger(0,"B",OBJPROP_STATE,0);
     }

   if(ObjectGetInteger(0,"S",OBJPROP_STATE)==1)
     {
      PutOrder(1,Bid,Lot);
      ObjectSetInteger(0,"S",OBJPROP_STATE,0);
     }

   if(OrdersTotal()>0 && ObjectGetInteger(0,"C",OBJPROP_STATE)==1)
     {
      CloseAll();
      ObjectSetInteger(0,"C",OBJPROP_STATE,0);
     }

   Comment("\n Profit: ",AllProfit(),
           "\n Minus: ",Points(),
           "\n Last Type: ",LastType());
  }
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+

но еще проще было ставить отложку вместо стопа сразу или закрывать по профиту

AM2

19 декабря 2020, 10:02

Советник-усреднитель на основе индикатора Prise Border и модели поглощения. / Стол заказов MQL 15

0

в чем я не прав? в том что ваш советник не видит индикатор?

AM2

18 декабря 2020, 18:44

Советник-усреднитель на основе индикатора Prise Border и модели поглощения. / Стол заказов MQL 15

0

Где Вы видите перерисовку канала там?

там я вижу значения индикатора по нулям. в этом вся причина

AM2

18 декабря 2020, 18:27

Советник-усреднитель на основе индикатора Prise Border и модели поглощения. / Стол заказов MQL 15

0

вот о чем я вас просил:

теперь понятно?

AM2

18 декабря 2020, 18:19

Советник-усреднитель на основе индикатора Prise Border и модели поглощения. / Стол заказов MQL 15

0

Там модель поглощения образовалась за пределами канала.

в момент возникновения сигнала цены выше ниже канала. если вы утверждаете обратное приведите скрин сразу после установки ордера а не после того как канал перерисовался

AM2

18 декабря 2020, 18:00

Советник-усреднитель на основе индикатора Prise Border и модели поглощения. / Стол заказов MQL 15

0

готово: www.opentraders.ru/downloads/2885/

AM2

17 декабря 2020, 20:57

Советник на отложенных ордерах / Стол заказов MQL 10

0

можно сделать вторую попытку, но с поручителем

AM2

17 декабря 2020, 17:37

Переписать советник Фибоначчи для МТ5 / Стол заказов MQL 13

0

с поручителем можно ожидать

AM2

17 декабря 2020, 17:35

Советник на отложенных ордерах / Стол заказов MQL 10

0

мне непонятно это тз

AM2

16 декабря 2020, 20:55

Советник на BetterVolume / Стол заказов MQL 5

0

добавил стопы: www.opentraders.ru/downloads/2882/

AM2

16 декабря 2020, 20:44

Переписать советник Фибоначчи для МТ5 / Стол заказов MQL 13

0

переписать можно

AM2

16 декабря 2020, 20:42

Чтение данных из файла CSV / Стол заказов MQL 13

0

сначала считываем параметры и записываем в файл, затем считываем то что нужно:

www.opentraders.ru/downloads/2884/

AM2

16 декабря 2020, 20:39

Обновление для советника / Стол заказов MQL 12

0

дело в том что его когда устанавливаешь на график он устанавливает пивот, и должен через час обновить пивот, но этого не происходит,

я вам предлагал написать советник с нуля в том числе и эту функцию а вы ушли в такие дебри

AM2

16 декабря 2020, 17:51

Советник на отложенных ордерах / Стол заказов MQL 10

0

подробнее со скринами

AM2

16 декабря 2020, 17:45

Советник-усреднитель на основе индикатора Prise Border и модели поглощения. / Стол заказов MQL 15

0

на 21-е

AM2

16 декабря 2020, 17:40

Обновление для советника / Стол заказов MQL 12

0

Задание чтоб советник сам себя обновлял на графике

как вы себе это представляете?

AM2

15 декабря 2020, 22:21

Советник на BetterVolume / Стол заказов MQL 5

0

готово: www.opentraders.ru/downloads/2882/

AM2

15 декабря 2020, 22:11

Обновление для советника / Стол заказов MQL 12

0

мне будет проще написать советник с нуля, при условии если задание простое

AM2

15 декабря 2020, 21:48

Модификатор тейка / Стол заказов MQL 5

0

готово:


//+------------------------------------------------------------------+
//|                                                    BuySell53.mq4 |
//|                                              Copyright 2020, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lot        = 0.1;      // лот позы
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 150;      // язь
extern int Delta         = 300;      // расстояние от цены
extern int Step          = 200;      // шаг
extern int Count         = 5;        // число ордеров
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   PutButton("B",100,160,"BUY LIMIT");
   PutButton("S",100,120,"SELL LIMIT");
   PutButton("C",100,80,"CLOSE");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   ObjectDelete(0,"B");
   ObjectDelete(0,"S");
   ObjectDelete(0,"C");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutButton(string name,int x,int y,string text)
  {
   ObjectCreate(0,name,OBJ_BUTTON,0,0,0);
//--- установим координаты кнопки
   ObjectSetInteger(0,name,OBJPROP_XDISTANCE,x);
   ObjectSetInteger(0,name,OBJPROP_YDISTANCE,y);
//--- установим размер кнопки
   ObjectSetInteger(0,name,OBJPROP_XSIZE,80);
   ObjectSetInteger(0,name,OBJPROP_YSIZE,30);
//--- установим угол графика, относительно которого будут определяться координаты точки
   ObjectSetInteger(0,name,OBJPROP_CORNER,3);
//--- установим текст
   ObjectSetString(0,name,OBJPROP_TEXT,text);
//--- установим шрифт текста
   ObjectSetString(0,name,OBJPROP_FONT,"Arial");
//--- установим размер шрифта
   ObjectSetInteger(0,name,OBJPROP_FONTSIZE,9);
//--- установим цвет текста
   ObjectSetInteger(0,name,OBJPROP_COLOR,Red);
//--- установим цвет фона
   ObjectSetInteger(0,name,OBJPROP_BGCOLOR,White);
//--- установим цвет границы
   ObjectSetInteger(0,name,OBJPROP_BORDER_COLOR,Blue);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
   ObjectSetInteger(0,name,OBJPROP_HIDDEN,false);
//--- установим приоритет на получение события нажатия мыши на графике
   ObjectSetInteger(0,name,OBJPROP_ZORDER,0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot,NormalizeDouble(price,_Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double LastTake()
  {
   double pr=0;

   for(int i=0; i<OrdersTotal(); i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
              {
               pr=OrderTakeProfit();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ModifyOrders()
  {
   bool m=1;
   double tp=NormalizeDouble(LastTake(),Digits);

   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {            
            if(OrderTakeProfit()!=tp && OrderType()<2)
              {
               m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderStopLoss(),tp,0,Yellow);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type=-1)
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type || type==-1)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()>1)
      ModifyOrders();

   if(ObjectGetInteger(0,"B",OBJPROP_STATE)==1)
     {
      for(int i=0; i<Count; i++)
         PutOrder(2,Bid-Delta*_Point-Step*_Point*i);
      ObjectSetInteger(0,"B",OBJPROP_STATE,0);
     }

   if(ObjectGetInteger(0,"S",OBJPROP_STATE)==1)
     {
      for(int i=0; i<Count; i++)
         PutOrder(3,Bid+Delta*_Point+Step*_Point*i);
      ObjectSetInteger(0,"S",OBJPROP_STATE,0);
     }

   if(OrdersTotal()>0 && ObjectGetInteger(0,"C",OBJPROP_STATE)==1)
     {
      CloseAll();
      ObjectSetInteger(0,"C",OBJPROP_STATE,0);
     }

   Comment(LastTake());
  }
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+

AM2

15 декабря 2020, 18:20

Советник на BetterVolume / Стол заказов MQL 5

0

на 17-е

AM2

15 декабря 2020, 17:44

Новости сообщества:

Рейтинг брокеров FOREX

Из недавнего:

Авторизация

Новости сообщества:

Рейтинг брокеров FOREX

Из недавнего: