Комментарии / Публикации AM2 / OpenTraders - блогплатформа для трейдеров финансовых рынков

Всё хорошо, только можно сделать, чтобы по ходу движения лот был постоянный, а против, то тогда усреднялся. Или в параметр добавить разделение:
— увеличение лота доливка
— увеличение лота усреднения

этого не было в первоначальном тз, значит пойдет на следующий топик. входы по ма поправил: www.opentraders.ru/downloads/2073/

AM2

12 сентября 2018, 17:50

Советник по индикатору FFx_MACD / Стол заказов MQL 8

0

пользовательский индикатор, на таких часто сигнал не соответствует визуальному изображению. пользуйтесь стандартными.

AM2

11 сентября 2018, 21:55

Советник по тренду / Стол заказов MQL 20

0

готово: www.opentraders.ru/downloads/2073/

AM2

11 сентября 2018, 20:24

Закрытие по общему профиту с указанных пар / Стол заказов MQL 20

+1

А обратный профит тоже нужная вещь!

if(all>pro && pro>0)

только править надо на

if(all>pro)

AM2

10 сентября 2018, 20:40

Закрытие по общему профиту с указанных пар / Стол заказов MQL 20

+1

проверил на отрицательном профите чтобы не ждать, все закрыл нормально.

AM2

10 сентября 2018, 20:31

Закрытие по общему профиту с указанных пар / Стол заказов MQL 20

+1

открыл позы, жду закрытия


//+------------------------------------------------------------------+
//|                                                      Symbols.mq4 |
//|                                              Copyright 2018, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

input string s1="EURUSD";
input string s2="GBPUSD";
input string s3="USDCHF";
input double pro=1;
input int slip=30;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Профит всех ордеров по типу ордера                               |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1,string symb="")
  {
   double pr=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==symb)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//| Закрытие позиции по типу ордера                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1,string symb="")
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==symb)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),MarketInfo(symb,MODE_BID),slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),MarketInfo(symb,MODE_ASK),slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double all=AllProfit(-1,s1)+AllProfit(-1,s2)+AllProfit(-1,s3);
   
   if(all>pro && pro>0)
     {
      CloseAll(-1,s1);
      CloseAll(-1,s2);
      CloseAll(-1,s3);
     }

   Comment("\n Profit "+s1+": ",AllProfit(-1,s1),
           "\n Profit "+s2+": ",AllProfit(-1,s2),
           "\n Profit "+s3+": ",AllProfit(-1,s3),
           "\n All Profit: ",all);
  }
//+------------------------------------------------------------------+

AM2

10 сентября 2018, 20:24

RSI + AC + SMA / Стол заказов MQL 8

+1

варик с открытием свечи:


//+------------------------------------------------------------------+
//|                                                         Poka.mq4 |
//|                                              Copyright 2018, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 2;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int MAPeriod      = 5;        // период МА
extern int RSIPeriod     = 14;       // период RSI
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits); else sl=NormalizeDouble(Close[1]+MarketInfo(NULL,MODE_STOPLEVEL)*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits); else sl=NormalizeDouble(Close[1]-MarketInfo(NULL,MODE_STOPLEVEL)*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   for(int i=OrdersHistoryTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_HISTORY))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderProfit()>0) break;
            if(OrderProfit()<0)
              {
               lot=OrderLots()*KLot;
               break;
              }
           }
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double ac1=iAC(NULL,0,Shift);
   double ac2=iAC(NULL,0,Shift+1);
   double ma=iMA(NULL,0,MAPeriod,0,0,0,Shift);
   double rsi1=iRSI(NULL,0,RSIPeriod,0,Shift);
   double rsi2=iRSI(NULL,0,RSIPeriod,0,Shift+1);

   if(Bid>ma && rsi1>50 && rsi2<50 && ac1>ac2) PutOrder(0,Ask);
   if(Bid<ma && rsi1<50 && rsi2>50 && ac1<ac2) PutOrder(1,Bid);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0])
     {
      if(CountTrades()<1) OpenPos();
      t=Time[0];
     }
  }
//+------------------------------------------------------------------+

AM2