Opentraders - это независимое сообщество, создаваемое трейдерами и для трейдеров. Присоединяйтесь, нам по пути!

Войти
Регистрация

Скачать терминал

Индикатор для МТ4 / Стол заказов MQL 11

0

По какому алгоритму делать? Если так как в ТЗ, то это будет выглядеть так:


//+------------------------------------------------------------------+
//|                                                    BarsColor.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

#property indicator_chart_window

input int n=10;
input int d=200;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutRect(string name,datetime t1,double p1,datetime t2,double p2,color clr)
  {
   ObjectDelete(0,name);
//--- создадим прямоугольник по заданным координатам
   ObjectCreate(0,name,OBJ_RECTANGLE,0,t1,p1,t2,p2);
//--- установим цвет прямоугольника
   ObjectSetInteger(0,name,OBJPROP_COLOR,clr);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   for(int i=0;i<1000;i++)
     {
      if(MathAbs(close[i]-close[i+n])>d*Point) PutRect((string)i,time[i],close[i],time[i+n],close[i+n],Red);
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+

5 октября 2017, 18:20

Увеличение лота в советнике / Стол заказов MQL 2

0

Подербанили мой код

www.opentraders.ru/downloads/1678/

5 октября 2017, 01:46

Доработка советника на пробой / Стол заказов MQL 9

+1

Какой древний код

www.opentraders.ru/downloads/1677/

5 октября 2017, 01:25

Стоповый советник / Стол заказов MQL 11

0

Вам сюда

www.opentraders.ru/downloads/1676/

5 октября 2017, 00:48

Стоповый советник / Стол заказов MQL 11

0

Готово:


//+------------------------------------------------------------------+
//|                                                       ProBoy.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал 
extern string CloseTime  = "23:55";  // время закрытия
extern int Magic         = 123;      // магик
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 30.04.2009                                                     |
//|  Описание : Возвращает флаг разрешения торговли по времени.                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    hb - часы времени начала торговли                                       |
//|    mb - минуты времени начала торговли                                     |
//|    he - часы времени окончания торговли                                    |
//|    me - минуты времени окончания торговли                                  |
//+----------------------------------------------------------------------------+
bool isTradeTimeInt(int hb=0,int mb=0,int he=0,int me=0)
  {
   datetime db, de;           // Время начала и окончания работы
   int      hc;               // Часы текущего времени торгового сервера

   db=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)hb+":"+(string)mb);
   de=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)he+":"+(string)me);
   hc=TimeHour(TimeCurrent());

   if(db>=de)
     {
      if(hc>=he) de+=24*60*60; else db-=24*60*60;
     }

   if(TimeCurrent()>=db && TimeCurrent()<=de) return(True);
   else return(False);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Подсчет ордеров по типу                                          |
//+------------------------------------------------------------------+
int CountOrders(int type)
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==type) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Удаление отложенных ордеров                                      |
//+------------------------------------------------------------------+
void DelOrder()
  {
   bool del;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()>1) del=OrderDelete(OrderTicket());
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   int spread=(int)MarketInfo(NULL,MODE_SPREAD);

   if(CountTrades()<1 && isTradeTimeInt(StartHour,StartMin,EndHour,EndMin))
     {
      if(CountOrders(4)<1 && Bid<High[Shift]) PutOrder(4,High[Shift]+2*spread*Point);
      if(CountOrders(5)<1 && Bid>Low[Shift]) PutOrder(5,Low[Shift]-2*spread*Point);
     }

   if(TimeCurrent()==StringToTime(CloseTime))
     {
      CloseAll();
      DelOrder();
     }
  }
//+------------------------------------------------------------------+

4 октября 2017, 17:57

Доработка советника на пробой / Стол заказов MQL 9

0

Сегодня посмотрю как и обещал.

4 октября 2017, 17:30

Стоповый советник / Стол заказов MQL 11

0

Сегодня или завтра посмотрю.

4 октября 2017, 17:29

Советник MT4 на индикаторе Parabolic ZZ (ZigZag+Fibo) / Стол заказов MQL 8

0

Не раньше следующей недели буду смотреть.

4 октября 2017, 17:26

Шахматный советник / Стол заказов MQL 10

0

В пятницу буду смотреть.

4 октября 2017, 17:23

Индикатор для МТ4 / Стол заказов MQL 11

0

В четверг буду смотреть.

3 октября 2017, 20:36

Допилить закрытие всех ордеров по времени в советнике Fibo / Стол заказов MQL 7

0

Готово: www.opentraders.ru/downloads/1675/

3 октября 2017, 19:42

Доработка совы / Стол заказов MQL 12

+1

Добавил: www.opentraders.ru/downloads/1673/

3 октября 2017, 19:06

Допилить закрытие всех ордеров по времени в советнике Fibo / Стол заказов MQL 7

0

возможность закрывать все открытые ордера по времени

Здесь подробнее пожалуйста. Это экспирация отложек или закрытие открытых поз?

3 октября 2017, 18:53

Доработка советника на пробой / Стол заказов MQL 9

0

Завтра буду смотреть.

3 октября 2017, 17:22

Доработка совы / Стол заказов MQL 12

0

Так слишком много условий разнообразных, запутаться можно. Посмотрю еще сегодня.

3 октября 2017, 17:21

Допилить закрытие всех ордеров по времени в советнике Fibo / Стол заказов MQL 7

0

Сегодня буду смотреть.

3 октября 2017, 17:19

Доработка совы / Стол заказов MQL 12

0

Делал по ТЗ

3 октября 2017, 07:18

Доработка совы / Стол заказов MQL 12

0

Скинул: www.opentraders.ru/downloads/1673/

2 октября 2017, 22:10

Доработка совы / Стол заказов MQL 12

0

Поверх старого залить или новым файлом в базу скинуть?


//+------------------------------------------------------------------+
//|                                                    Blohastik.mq4 |
//|                                              Copyright 2017, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 2;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 555;      // лось
extern int TakeProfit    = 555;      // язь
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик
extern bool Mac          = true;     // фильтр по MACD
extern bool Sto          = true;     // фильтр по стоху

extern string IndName    = "BBands_Stop_v1";
extern int    Length     = 20;       // Bollinger Bands Period
extern int    Deviation  = 2;        // Deviation was 2
extern double MoneyRisk  = 1.00;     // Offset Factor

extern string N1         = "Настройки стоха";
extern int KPeriod       = 5;
extern int DPeriod       = 3;
extern int Slowing       = 3;
extern int Level         = 30;

extern string N2         = "Настройки SAR";
input double  SARStep    = 0.02;     // Step
input double  SARMaximum = 0.2;      // Maximum

extern string N3="Настройки MACD";
input int FastEMA=12;   // Fast EMA Period
input int SlowEMA=26;   // Slow EMA Period
input int SignalSMA=9;  // Signal SMA Period

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 30.04.2009                                                     |
//|  Описание : Возвращает флаг разрешения торговли по времени.                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    hb - часы времени начала торговли                                       |
//|    mb - минуты времени начала торговли                                     |
//|    he - часы времени окончания торговли                                    |
//|    me - минуты времени окончания торговли                                  |
//+----------------------------------------------------------------------------+
bool isTradeTimeInt(int hb=0,int mb=0,int he=0,int me=0)
  {
   datetime db, de;           // Время начала и окончания работы
   int      hc;               // Часы текущего времени торгового сервера

   db=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)hb+":"+(string)mb);
   de=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" "+(string)he+":"+(string)me);
   hc=TimeHour(TimeCurrent());

   if(db>=de)
     {
      if(hc>=he) de+=24*60*60; else db-=24*60*60;
     }

   if(TimeCurrent()>=db && TimeCurrent()<=de) return(True);
   else return(False);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//| Результат последней сделки                                       |
//+------------------------------------------------------------------+
int LastDealResult()
  {
   int result=0;
   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
        {
         if(OrderProfit()>0)
           {
            result=1;//tp  
           }
         if(OrderProfit()<0)
           {
            result=2;//sl  
           }
        }
     }
   return(result);
  }
//+------------------------------------------------------------------+
//| Тип последней сделки                                             |
//+------------------------------------------------------------------+
int LastDealType()
  {
   int type=0;
   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
        {
         if(OrderType()==0)
           {
            type=1;//buy  
           }
         if(OrderType()==1)
           {
            type=2;//sell  
           }
        }
     }
   return(type);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double blue = iCustom(NULL,0,IndName,Length,Deviation,MoneyRisk,0,Shift);
   double red  = iCustom(NULL,0,IndName,Length,Deviation,MoneyRisk,1,Shift);

   double sar1  = iSAR(NULL,0,SARStep,SARMaximum,Shift);
   double sar2  = iSAR(NULL,0,SARStep,SARMaximum,Shift+1);
   double sto=iStochastic(NULL,0,KPeriod,DPeriod,Slowing,0,0,0,Shift);

   double macd=iMACD(NULL,0,FastEMA,SlowEMA,SignalSMA,0,0,Shift);

   bool buy=blue>0 && sar1<Bid && sar2>Bid && sto<100-Level && macd>0;
   bool sell=red>0 && sar1>Bid && sar2<Bid && sto>Level && macd<0;

   if(!Sto)
     {
      buy=blue>0 && sar1<Bid && sar2>Bid && macd>0;
      sell=red>0 && sar1>Bid && sar2<Bid && macd<0;
     }

   if(!Mac)
     {
      buy=blue>0 && sar1<Bid && sar2>Bid && sto<100-Level;
      sell=red>0 && sar1>Bid && sar2<Bid && sto>Level;
     }

   if(buy)
     {
      PutOrder(0,Ask);
     }

   if(sell)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderProfit()<0)
        {
         lot=OrderLots()*KLot;
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(isTradeTimeInt(StartHour,StartMin,EndHour,EndMin))
     {
      if(t!=Time[0])
        {
         if(CountTrades()<1) OpenPos();
         t=Time[0];
        }
     }
  }
//+------------------------------------------------------------------+

2 октября 2017, 21:52

Допилить закрытие всех ордеров по времени в советнике Fibo / Стол заказов MQL 7

0

Вам можно найти поручителя с 3-м и выше уровнем.

2 октября 2017, 17:20

← предыдущая следующая →

Страницы:
←
303
304
305
306
307
308
309
310
311
... последняя

Перейти в чат трейдеров ->

Новости сообщества:

19 августа 2024, 17:10
Починили поиск на сайте
Поиск доступен на каждой странице сверху справа
Подробнее...
13 августа 2024, 15:18
Чат размещается по новой ссылке

Подробнее...

Рейтинг брокеров FOREX

По версии OpenTraders

Рейтинг брокеров FOREX

Весь рейтинг
Как узнать IP торгового сервера?

Из недавнего:

Нажмите, чтобы обновить

AM2
17 мая 2025, 19:17

→

Зоны (44) в Стол заказов MQL
опишите подробно со скринами нужный вам алгоритм и я п�... <>[Читать..]

Evgen123
16 мая 2025, 22:22

→

Aud/usd bay (6) в Блог им. Evgen123
::
По тп закрылось, но все равно день сегодня в минус,... <>[Читать..]

qwerty1234567890
16 мая 2025, 15:09 → Алерт к индикатору OsMa (7) в Стол заказов MQL
Спасибо Всем!!! <>[Читать..]

AM2
14 мая 2025, 18:43

→

советник круглые уровни на графике и масд (16) в Стол заказов MQL
Это всё есть в настройках

input string III = "Main Inputs"; input... <>[Читать..]

pekyum
12 мая 2025, 17:58

→

Распределение прибыли на Форекс (16) в Блог им. alehus
Вы можете сегодня можете начать зарабатывать деньги в лучшем... <>[Читать..]

Shiva
8 мая 2025, 11:11

→

Индикатор Candle and Volume (7) в Стол заказов MQL
Здравствуйте! А, какой параметр в VOLUME?
<>[Читать..]

poker
30 апреля 2025, 06:43

→

Поправить код для tradingview (1) в Стол заказов MQL
Короче разобрался. Работает только на тайфреймах от М1 до... <>[Читать..]

AM2
28 апреля 2025, 18:31

→

Доработка советника (19) в Стол заказов MQL

Добавить возможность входа динамическим лотом от... <>[Читать..]

AM2
25 апреля 2025, 15:14 → alert (9) в Стол заказов MQL
1000р. доделать осталось немного <>[Читать..]

verta81
24 апреля 2025, 09:04

→

Нужен советник для МТ5, полный аналог спот grid bot на бирже Bybit (7) в Стол заказов MQL
@V_trueE
В ТГ напишите, все детали обсудим. <>[Читать..]

Все комментарии >>

Opentraders.ru: info@opentraders.ru; ©2009 - 2025

Общая информация: О проекте; Наша команда; Предупреждение о рисках; Пользовательское cоглашение; Условия использования; Рекламодателям; Контакты

Торговля: Инструкция по FOREX для начинающих; Сравнение FOREX и биржевого рынка; Рейтинг брокеров Forex; Расписание торговых сессий; Монитор Forex (графики, календарь)

Наши сервисы и услуги: Forex VPS; Тестовая лаборатория; Рейтинг советников Форекс; Файловое хранилище; Конкурсы от брокеров Форекс; Инвесторам; Новости: финансы, бизнес, экономика

MetaTrader: Скачать MetaTrader 5; Начало работы с терминалом; Мобильная версия терминала; Язык MQL5 для создания советников

Структура сообщества: Главная; Пользователи; Группы; Стены; Лента комментариев; Избранное

Внимание! Торговля и инвестирование на финансовых рынках сопряжены с повышенным риском потери капитала!
OpenTraders - информационный ресурс, не ведет брокерскую или дилерскую деятельность, не открывает счета. Все материалы на ресурсе носят информационный характер и не являются побуждением к действию. Администрация сайта может не соглашаться с мнением авторов. См. Предупреждение о рисках
Сайт работает на территории СНГ. Любая вероятная реклама направлена исключительно на жителей за пределами Российской Федерации, если явно не оговорено обратное. Пользователи самостоятельно несут ответственность за любую рекламу в своих материалах. См. Пользовательское cоглашение