Комментарии / Публикации AM2 / OpenTraders - блогплатформа для трейдеров финансовых рынков

Советник помошник / Стол заказов MQL 18

+5

Посмотрю, когда время придет. Только вот без этого!

AM2

30 октября 2016, 16:14

Советник помошник / Стол заказов MQL 18

+1

AM2

30 октября 2016, 14:02

Как протестировать свои ручные торговые стратегии / Торговые системы 8

0

Отложки таким же образом добавляются: кнопка — функция и готово

AM2

30 октября 2016, 13:14

Торгуем в тестере вручную. MT4 / Программирование на MQL 23

+1

Очень удобная штука! Надо будет еще свой вариант написать. Проверял это видео:

Не ужели правда!?

AM2

29 октября 2016, 22:45

Мой личный опыт в сервисах "Работа", "Маркет" и "Сигналы" / Блог им. AM2 4

+1

Есть ссылка на портфолио? Простенький дизайн обычно делаю сам, вот мое: vk.com/album44342494_204223866
Но какие то фишки с удовольствием позаимствую

AM2

29 октября 2016, 21:06

Советник на индикаторе psylevels v2.1 / Стол заказов MQL 3

+1

От 3-го уровня бесплатное выполнение в основном.

AM2

28 октября 2016, 16:06

Пипсовщики Славы / Торговые системы 22

0

Сегодня пробовал торговать на новостях, комиссия почти всю прибыль съела:

Нужно более сильное однонаправленное движение.

AM2

28 октября 2016, 16:03

Прошу Вас написать советник по стрелочному индикатору DSS Bressert Arrows TT(5-4 знака.) / Стол заказов MQL 24

0

Я свою норму знаю *drinks*

AM2

28 октября 2016, 10:18

Прошу Вас написать советник по стрелочному индикатору DSS Bressert Arrows TT(5-4 знака.) / Стол заказов MQL 24

+2

Я же работаю

Если я буду сидеть и ничего не делать, мне скажут: Ты за что здесь деньги получаешь!

AM2

28 октября 2016, 10:13

Прошу Вас написать советник по стрелочному индикатору DSS Bressert Arrows TT(5-4 знака.) / Стол заказов MQL 24

0

Все есть: www.opentraders.ru/downloads/1372/


//+------------------------------------------------------------------+
//|                                                     Bressert.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern int StopLoss      = 250;      // лось
extern int TakeProfit    = 150;      // язь
extern int BULevel       = 10;       // уровень БУ
extern int BUPoint       = 45;       // пункты БУ
extern int Slip          = 30;       // реквот
extern int Count         = 3;        // число ордеров
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

extern string IndName    = "DssBresert";
extern int EMAPeriod     =  12;
extern int StochPeriod   =  14;

datetime t=0;
bool b=true,s=true;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double blue1 = iCustom(NULL,0,IndName,EMAPeriod,StochPeriod,1,Shift);
   double red1  = iCustom(NULL,0,IndName,EMAPeriod,StochPeriod,2,Shift);
   double blue2 = iCustom(NULL,0,IndName,EMAPeriod,StochPeriod,1,Shift+1);
   double red2  = iCustom(NULL,0,IndName,EMAPeriod,StochPeriod,2,Shift+1);

   if(red2>0 && blue1>0 && b)
     {
      for(int i=0;i<Count;i++) PutOrder(0,Ask);
      b=false;s=true;
     }

   if(red1>0 && blue2>0 && s)
     {
      for(int i=0;i<Count;i++) PutOrder(1,Bid);
      s=false;b=true;
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll()
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==OP_SELL)
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double buy   = iCustom(NULL,0,IndName,EMAPeriod,StochPeriod,1,Shift);
   double sell  = iCustom(NULL,0,IndName,EMAPeriod,StochPeriod,2,Shift);

   if(CountTrades()<1 && t!=Time[0])
     {
      OpenPos();
      t=Time[0];
     }

   if(BULevel>0) BU();

   Comment("\n buy: ",buy,
           "\n sell: ",sell);
  }
//+------------------------------------------------------------------+

AM2

28 октября 2016, 09:30

Пипсовщики Славы / Торговые системы 22

0

Спасибо. Заработал, но как-то странно.
Наоткрывал. Ничего не закрыл. Ошибками сыплет про неправильные стопы.

Такой глюк в ветке был, поэтому пиши сразу свой вариант.

AM2

27 октября 2016, 21:40

Пипсовщики Славы / Торговые системы 22

0

Почему не можешь выложить свои настройки?

Потому что я там ничего не менял кроме спреда:

extern double SPREAD = 12;//макс. разрешённый спред

Сейчас специально делал меньше чем в терминале и тогда не работает:

AM2

27 октября 2016, 20:01

Пипсовщики Славы / Торговые системы 22

0

С текущими настройками на 5-ти знаке EURUSD M1 не открывает. Надо просить настройки у AM2.

Я оригинал когда гонял спред надо регулировать в настройках. А тест на М5 это уже самописный.

AM2

27 октября 2016, 18:09

Пипсовщики Славы / Торговые системы 22

0

Все есть граля

А что там на самом деле чуть позже смотреть буду. может и правда *neft*

резы с начала года постоянным лотом

AM2

27 октября 2016, 11:57

РОБОТ "МАРТЫШКА С РЕВЕРСОМ". / Стол заказов MQL 3

+1

Cделано: www.opentraders.ru/downloads/1373/


//+------------------------------------------------------------------+
//|                                                      Martini.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+

#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 2;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern int StopLoss      = 200;      // лось
extern int TakeProfit    = 200;      // язь
extern int BuySell       = 0;        // 0-Buy 1-Sell
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//| Результат последней сделки                                       |
//+------------------------------------------------------------------+
int LastDealResult()
  {
   int result=0;
   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
        {
         if(OrderProfit()>0)
           {
            result=1;//tp  
           }
         if(OrderProfit()<0)
           {
            result=2;//sl  
           }
        }
     }
   return(result);
  }
//+------------------------------------------------------------------+
//| Тип последней сделки                                       |
//+------------------------------------------------------------------+
int LastDealType()
  {
   int type=0;
   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
        {
         type=OrderType();
        }
     }
   return(type);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;

   if(OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS,MODE_HISTORY))
     {
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
        {
         if(OrderProfit()<0)
           {
            lot=OrderLots()*KLot;
           }
        }
     }
   if(lot>MaxLot)lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1)
     {
      if((BuySell<1 && LastDealResult()==0) || (LastDealResult()==1 && LastDealType()==0) || (LastDealResult()==2 && LastDealType()==1)) PutOrder(0,Ask);
      if((BuySell>0 && LastDealResult()==0) || (LastDealResult()==1 && LastDealType()==1) || (LastDealResult()==2 && LastDealType()==0)) PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+

AM2